@echo off
rem onwx-dash - LLMs on the AMD Ryzen AI Radeon GPU + NPU: run the server once from a console (Windows).
rem   start.bat C:\models\Qwen3.6-35B-A3B-UD-Q4_K_XL.gguf              a GGUF file (Qwen3.6-35B-A3B or Nemotron 3.5 Bolt)
rem   start.bat MODEL.gguf --port 8080 --context 32768              further options go to "onwx serve"
rem First run: finds / installs Python, creates .venv. Models: download them in the tray app's window (setup.bat).
setlocal
cd /d "%~dp0"
set PYTHONUTF8=1
set "MODEL="
set "FIRST=%~1"
if not "%FIRST%"=="" if not "%FIRST:~0,1%"=="-" (
    set "MODEL=%FIRST%"
    shift
)

if exist ".venv\installed.txt" goto args
if exist ".venv\Scripts\python.exe" goto install
call "%~dp0find_python.bat"
if not defined PY (
    pause
    exit /b 1
)
echo [setup] creating Python environment in .venv ...
%PY% -m venv .venv
if errorlevel 1 (
    echo [setup] could not create the Python environment.
    pause
    exit /b 1
)
:install
".venv\Scripts\python.exe" -m pip install "pip>=26.2.2"
".venv\Scripts\python.exe" -m pip install -e .
if errorlevel 1 (
    echo [setup] package installation failed.
    pause
    exit /b 1
)
echo ok> ".venv\installed.txt"

:args
set "ARGS="
:collect
if "%~1"=="" goto run
set "ARGS=%ARGS% %1"
shift
goto collect
:run
if not defined MODEL (
    echo usage: start.bat MODEL.gguf [options]
    pause
    exit /b 1
)
echo [start] %MODEL% ...
".venv\Scripts\onwx.exe" serve "%MODEL%" --open %ARGS%
pause