Download Neuronal.bat from amogaddy/neuronal: direct link, hf CLI and curl.
- Browser
- Download file 2.49 kB
-
https://huggingface.co/spaces/amogaddy/neuronal/resolve/main/Neuronal.bat
- Command line
-
hf download hf://spaces/amogaddy/neuronal/Neuronal.bat
-
curl -L -o Neuronal.bat https://huggingface.co/spaces/amogaddy/neuronal/resolve/main/Neuronal.bat
2.49 kB
| @echo off | |
| rem Avvia Neuronal e apre la pagina web in localhost. | |
| rem Se il motore e' gia' acceso, apre solo la pagina. | |
| setlocal | |
| chcp 65001 >nul | |
| title Neuronal | |
| set "ROOT=%~dp0" | |
| set "URL=http://127.0.0.1:8765/" | |
| curl -sf -o nul -m 2 "%URL%health" && goto open | |
| if exist "%ROOT%.preparazione" ( | |
| echo Questa e' la cartella di preparazione dell'installer, non un'installazione di Neuronal. | |
| echo Per usare Neuronal installalo con windows\Neuronal-Setup-1.0.0.exe | |
| pause | |
| exit /b 1 | |
| ) | |
| if not exist "%ROOT%build\neuronald.exe" ( | |
| echo Il motore non e' compilato. Dalla cartella del progetto esegui: | |
| echo cmake -S . -B build -G Ninja | |
| echo cmake --build build | |
| pause | |
| exit /b 1 | |
| ) | |
| rem modelli: in models\ (installazione) oppure il modello nella cartella principale (sviluppo) | |
| set "MISSING=" | |
| if not exist "%ROOT%models\neuronal.gguf" if not exist "%ROOT%neuronal.gguf" set "MISSING=1" | |
| if not exist "%ROOT%models\whisper-small\model.bin" set "MISSING=1" | |
| if not exist "%ROOT%models\piper\it_IT-riccardo-x_low.onnx" set "MISSING=1" | |
| if defined MISSING goto models | |
| goto start | |
| :models | |
| echo Mancano dei modelli di Neuronal (il modello, la voce o la trascrizione). | |
| choice /c SN /m "Li scarico adesso (fino a 5,5 GB)" | |
| if errorlevel 2 exit /b 1 | |
| set "PY=%ROOT%python\python.exe" | |
| if not exist "%PY%" set "PY=%ROOT%mind\.venv\Scripts\python.exe" | |
| "%PY%" "%ROOT%scripts\scarica_modelli.py" "%ROOT%models" --elenco "%ROOT%modelli.json" | |
| if errorlevel 1 ( | |
| echo Lo scaricamento non e' riuscito: controlla la connessione e riprova. | |
| pause | |
| exit /b 1 | |
| ) | |
| :start | |
| echo Accensione di Neuronal: caricamento del modello e mappatura del cervello... | |
| echo (circa 30 secondi; il motore gira nella finestra "Neuronal - motore": chiudila per spegnerlo) | |
| start "Neuronal - motore" /min powershell -NoProfile -ExecutionPolicy Bypass -File "%ROOT%scripts\start-neuronal.ps1" -Supervise | |
| rem servizio vocale per le chiamate: si collega da solo quando il motore e' pronto | |
| start "Neuronal - voce" /min "%ROOT%scripts\start-voice.bat" | |
| set /a tries=0 | |
| :wait | |
| set /a tries+=1 | |
| if %tries% gtr 90 ( | |
| echo Il motore non risponde dopo 3 minuti. Controlla la finestra "Neuronal - motore". | |
| pause | |
| exit /b 1 | |
| ) | |
| ping -n 3 127.0.0.1 >nul | |
| curl -sf -o nul -m 2 "%URL%health" || goto wait | |
| :open | |
| echo Neuronal e' pronto: %URL% | |
| echo Per il telefono: nella pagina premi il pulsante "Telefono" e inquadra il QR. | |
| start "" "%URL%" | |
| endlocal | |